The National Palace Museum Experience/The National Palace Museum Experience.iso/Programs/Panorama.dxr/00160_UI Toggle Help Button.ls

Text File | 1998-11-19 | 3.6 KB | 99 lines

property normalMember, NormalMemberNum, toggleMember, ImageCastLib, setting, tracking, outcurs, incurs, incursSet, customImage, customMask, oldcursor, useCustom

on translate_cursor me, setting, image, mask, Custom
  if Custom then
    set val to [member image, member mask]
    return val
  end if
  return setting
end

on mouseDown me
  set the tracking of me to 1
  Toggle(me)
end

on mouseEnter me
  if the tracking of me then
    Toggle(me)
  end if
end

on mouseLeave me
  if the tracking of me then
    Toggle(me)
  end if
end

on mouseUp me
  if the tracking of me then
    set the tracking of me to 0
  end if
end

on mouseUpOutSide me
  if the tracking of me then
    set the tracking of me to 0
  end if
end

on Toggle me
  setValue(me, not (the setting of me))
end

on setValue me, v_me
  global officehelp, helptrigger
  if v_me = 0 then
    set the member of sprite the spriteNum of me to the normalMember of me
    set the setting of me to 0
    turnoffhelp(officehelp)
    set helptrigger to 0
  else
    set the member of sprite the spriteNum of me to the toggleMember of me
    set the setting of me to 1
    turnonhelp(officehelp)
    set helptrigger to 1
  end if
  updateStage()
end

on beginSprite me
  global officehelp
  set oldcursor to the cursor of sprite the spriteNum of me
  set val to translate_cursor(me, the incursSet of me, customImage, customMask, useCustom)
  set the cursor of sprite the spriteNum of me to val
  set s to the spriteNum of me
  set the NormalMemberNum of me to the memberNum of sprite s
  set the ImageCastLib of me to the number of castLib the castLibNum of sprite s
  set the normalMember of me to member the NormalMemberNum of me of castLib the ImageCastLib of me
  set the toggleMember of me to member the toggleMemberNum of me of castLib the ImageCastLib of me
  setValue(me, the setting of me)
end

on getPropertyDescriptionList
  if the currentSpriteNum = 0 then
    set memdefault to 0
  else
    set memref to the member of sprite the currentSpriteNum
    set castLibNum to the castLibNum of memref
    set memdefault to member (the memberNum of member memref + 1) of castLib castLibNum
  end if
  set p_list to [#incursSet: [#comment: "Pointer Image:", #format: #cursor, #default: 1], #useCustom: [#comment: "Use Custom Pointer:", #format: #boolean, #default: 0], #customImage: [#comment: "Custom Image:", #format: #bitmap, #default: member 1], #customMask: [#comment: "Custom Mask:", #format: #bitmap, #default: member 1], #toggleMemberNum: [#comment: "Toggle Image:", #format: #graphic, #default: memdefault], #setting: [#comment: "Initially Toggled:", #format: #boolean, #default: 0]]
  return p_list
end

on SetToggleValue me, v_me
  if v_me = 0 then
    set the member of sprite the spriteNum of me to the normalMember of me
    set the setting of me to 0
  else
    set the member of sprite the spriteNum of me to the toggleMember of me
    set the setting of me to 1
  end if
  updateStage()
end

on getBehaviorDescription
  return "Makes a sprite work as a toggle button with automatic highlighting and mouse tracking. The behavior responds when clicked, or when the SetToggleValue or Toggle messages are receieved. Use the the UI Radio Group behavior to control toggle buttons in radio button groups." & RETURN & "PARAMETERS:" & RETURN & "ΓÇó Toggle Image - Choose the cast member to display when the button is toggled." & RETURN & "ΓÇó Initially Toggled - Turn this option to make the button toggled when it first appears." & RETURN & "MESSAGES:" & RETURN & "ΓÇó SetToggleValue {TRUE or FALSE} - Sets the toggle button." & RETURN & "ΓÇó Toggle - Switches the toggle button state."
end